Mercurial > hg-old > index.cgi

comparison m4/sleep.m4 @ 434:b8bf63962a99 3.0

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
Added various generated files for release
author lost@l-w.ca
date Fri, 29 Oct 2010 19:20:39 -0600
parents
children
comparison
equal deleted inserted replaced
433:b142b473f0ee 434:b8bf63962a99
1 # sleep.m4 serial 3
2 dnl Copyright (C) 2007-2010 Free Software Foundation, Inc.
3 dnl This file is free software; the Free Software Foundation
4 dnl gives unlimited permission to copy and/or distribute it,
5 dnl with or without modifications, as long as this notice is preserved.
6
7 AC_DEFUN([gl_FUNC_SLEEP],
8 [
9 AC_REQUIRE([gl_UNISTD_H_DEFAULTS])
10 dnl We expect to see the declaration of sleep() in a header file.
11 dnl Older versions of mingw have a sleep() function that is an alias to
12 dnl _sleep() in MSVCRT. It has a different signature than POSIX sleep():
13 dnl it takes the number of milliseconds as argument and returns void.
14 dnl mingw does not declare this function.
15 AC_CHECK_DECLS([sleep], , , [#include <unistd.h>])
16 AC_CHECK_FUNCS_ONCE([sleep])
17 if test $ac_cv_have_decl_sleep != yes; then
18 HAVE_SLEEP=0
19 AC_LIBOBJ([sleep])
20 else
21 dnl Cygwin 1.5.x has a bug where sleep can't exceed 49.7 days.
22 AC_CACHE_CHECK([for working sleep], [gl_cv_func_sleep_works],
23 [AC_RUN_IFELSE([AC_LANG_PROGRAM([[
24 #include <errno.h>
25 #include <unistd.h>
26 #include <signal.h>
27 static void
28 handle_alarm (int sig)
29 {
30 if (sig != SIGALRM)
31 _exit (2);
32 }
33 ]], [[
34 /* Failure to compile this test due to missing alarm is okay,
35 since all such platforms (mingw) also lack sleep. */
36 unsigned int pentecost = 50 * 24 * 60 * 60; /* 50 days. */
37 unsigned int remaining;
38 signal (SIGALRM, handle_alarm);
39 alarm (1);
40 remaining = sleep (pentecost);
41 return !(pentecost - 10 < remaining && remaining <= pentecost);]])],
42 [gl_cv_func_sleep_works=yes], [gl_cv_func_sleep_works=no],
43 [gl_cv_func_sleep_works="guessing no"])])
44 if test "$gl_cv_func_sleep_works" != yes; then
45 REPLACE_SLEEP=1
46 AC_LIBOBJ([sleep])
47 fi
48 fi
49 ])